三流君のソースコード置き場

ブログにソースコードをアップして、ブログの検索機能で利用してます(利用予定です)

よく検索されるキーワード: [VBA]/ [VBS]/ [CreateObject]/ [Excel]/ [ADO]


SQL UPDATE文でデータを更新する

ブログに過去のソースコードをアップして、ブログの検索機能で利用してます(利用予定です)
※古くさいコードが多いです・・・



ソースコード

<%@LANGUAGE=VBScript%>
<% Response.CacheControl = "no-cache" %>
<% Response.AddHeader "Pragma", "no-cache" %>
<% Response.Expires = -1 %>
<html>
<head><META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=x-sjis">
<title>ASP フォームに更新のボタンを作成します</title>
</head>
<body>
<h1>ASPフォームに更新のボタンを作成します</h1>
test033-1.asp<br>
<hr>
ここで、更新データを入力させ、<br>
ACTION='test033-2.asp'<br><br>
実際の更新処理(SQL UPDATE発行は)はtest033-2.aspで行ってます。<br>
ここでは、データのIDを隠し項目で作成して、<br>
type='hidden' NAME='UPDATE_ID' VALUE='999'<br>
として、更新データ(Text)と一緒にtest033-2.aspを呼び出してます。<br>
※データを入力して更新ボタンを押して、確認してみてください<br>
<%  '関数をコールする
    Call TEST_MAKE_DATA()
%>
<HR>
終了です。<br>
<A href="test029-1.asp">データ確認と登録(データを増やす)</a><br>
<A href="test032-1.asp">データ削除</a><br>


</body>
</html>

<% 'データ表示と更新ボタン生成
Sub TEST_MAKE_DATA()

  'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
  Set db=Server.CreateObject("ADODB.Connection")

  '.Provider?プロバイダー?通信会社?じゃなくって
  'データアクセスにはJet.OLEDB.4.0を使うことを設定
  db.Provider = "Microsoft.Jet.OLEDB.4.0"

  '次に、接続DBの位置を渡すので、Server.MapPathで変換して渡す
  db.ConnectionString = Server.MapPath("db029.mdb")

  'やっとデータベースを開ける
  db.open

  'SQL文を作る
  strSQL = "Select * From KANSOU "  '感想(KANSOU)テーブルから全項目(*)セレクト
  strSQL = strSQL & "ORDER BY WriteTime DESC"              '並べ替えは時間の降順

  'お約束のレコードセットの作成 SQL文の発行
  Set rs = db.Execute(strSQL)

  'オマケで画面にデータ表示
  Response.Write "<hr>ボタンを作成するために発行する(した)SQL文は<br><B><font color='green'>"
  Response.Write strSQL & "</font></B><br>です<hr>"

  Response.Write "<b>修正データをテキストボックス</b>へ入れて更新ボタンを押して<BR>"

  'データの表示をテーブルで行う
  Response.Write "<TABLE Border='1'>"

  '見出しをバカっぽく、そのまま書き込む
  Response.Write "<TR>"
  Response.Write "<TD>アクション</TD>"
  Response.Write "<TD>日付</TD>"
  Response.Write "<TD>区分</TD>"
  Response.Write "<TD>NO.</TD>"
  Response.Write "<TD>感想</TD>"
  Response.Write "</TR>"

  'お約束のEOFまでループは(データが無くなるまでループ)、
  Do While rs.EOF = False   'レコードセットの.EOFがFalseの間
    'フォームを作成する
    Response.Write "<FORM ACTION='test033-2.asp' METHOD='POST'>"
    Response.Write "<TR>"   '内容を表示する、行開始のタグ<TR>
    Response.Write "<TD>"
       'IDを隠し項目(UPDATE_ID)にする
    Response.Write "<INPUT type='hidden' NAME='UPDATE_ID' VALUE='"
    Response.Write rs.Fields.Item("ID") & "'>" 
       'ボタンは普通に作成する
    Response.Write "<INPUT TYPE='submit' VALUE='更新'>"
    Response.Write "</TD>"
    '中身を表示
    Response.Write "<TD>" & rs.Fields.Item("WriteTime") & "</TD>"
    Response.Write "<TD>" & rs.Fields.Item("F_KUBUN") & "</TD>"
    If rs.Fields.Item("F_NO") = 0 Then '0の全体かチェック
      Response.Write "<TD>全体</TD>"
    Else
      Response.Write "<TD>" & rs.Fields.Item("F_NO") & "</TD>" 'NO表示
    End If
    Response.Write "<TD>" & rs.Fields.Item("F_MEMO") & "<br>"
    Response.Write "修正: <INPUT TYPE='text' VALUE='ここにデータを入力してね' NAME='UPD_MEMO' SIZE=40>"
    Response.Write "</TD>"
    Response.Write "</TR>"
    Response.Write "</FORM>"    'フォームを閉じる
    '次のレコードにポインタを移動する
    rs.MoveNext    'これを忘れると悲惨なことに、、、
  Loop

  Response.Write "</TABLE>"  'テーブルは終わりです

  Response.Write "※修正したい行のデータを変更後、更新ボタンを押して下さい<BR>"

  '開いていたレコードセットを閉じる
  rs.Close

  'データベースも閉じようよ
  db.Close

  'お行儀よくオブジェクトも開放しましょう(通常は自動的に解放されるけど)
  Set db = Nothing

End Sub
%>

<%@LANGUAGE=VBScript%>
<% Response.CacheControl = "no-cache" %>
<% Response.AddHeader "Pragma", "no-cache" %>
<% Response.Expires = -1 %>
<html>
<head><META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=x-sjis">
<title>更新のSQL UPDATE文を発行する</title>
</head>
<body>
<h2>更新のSQL UPDATE文を発行する</h2>
test033-2.asp<br>
<hr>
<%  '関数をコールする
    Call TEST_UPDATE_DATA()
%>
<HR>
終了です。<br>
<A href="test033-1.asp">再度更新選択処理へ</a><br>
<A href="test032-1.asp">削除処理へ</a><br>
<A href="test029-1.asp">データ確認と登録</a><br>


</body>
</html>

<% '更新処理
Sub TEST_UPDATE_DATA()

  'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
  Set db=Server.CreateObject("ADODB.Connection")
  '.Provider?プロバイダー?通信会社?じゃなくって
  'データアクセスにはJet.OLEDB.4.0を使うことを設定
  db.Provider = "Microsoft.Jet.OLEDB.4.0"
  '次に、接続DBの位置を渡すので、Server.MapPathで変換して渡す
  db.ConnectionString = Server.MapPath("db029.mdb")
  'やっとデータベースを開ける
  db.open

  '条件のチェック
  If Request.Form("UPDATE_ID") <> "" Then
    'IDを条件にSQL UPDATE文を作る
    strSQL = "UPDATE KANSOU"  '感想(KANSOU)テーブルを更新するので
    strSQL = strSQL & " Set F_MEMO = '" & Left(Request.Form("UPD_MEMO"),20) & "'"
    strSQL = strSQL & ", WriteTime = #" & Now & "#"
    strSQL = strSQL & " Where ID=" & Request.Form("UPDATE_ID")
    'オマケで画面にデータ表示
    Response.Write "<hr>発行する(した)SQL文は<br><B><font color='green'>"
    Response.Write strSQL & "</font></B><br>です<hr>"
    'SQL文の発行
    db.Execute(strSQL)
  Else
    Response.Write "<hr><font color='red'>条件を受け取れませんでした</font><br>"
  End If
  'データベースも閉じようよ
  db.Close
  'お行儀よくオブジェクトも開放しましょう(通常は自動的に解放されるけど)
  Set db = Nothing

End Sub
%>

↑をテスト実行する→ http://www.ken3.org/cgi-bin/test/test033-1.asp実行する


三流君ASPでフォーム関係の解説とサンプル
三流君ASPでADO MDB接続関係の解説とサンプル
三流君ASPでADO Excel接続関係の解説ページとサンプル
三流君ASPでADO CSV接続関係の解説ページとサンプル
三流君ASPでテキストファイル関係の解説とサンプルページ
三流君ASP VBScript関数の解説とサンプル



三流君ASPで遊ぶ、失敗する

挨拶・自己紹介:
失敗続きのAB型の変わり者 :三流プログラマー Ken3です
フリーのエンジニア・個人事業主です・・と書くと聞こえはイイが(それとなくカッコよく聞こえるが)、 現在は小さな案件の受注請負 と 短期派遣 で 日々つつましく?ほそぼそと暮らしてます。
(※詳細は[三流君 三流プログラマーとは?]を見てください)


Ken3 ホームページ 目次

分類:HPを大きく分けると4つの柱(分類)です。
・[Excel/Access VBA]の解説
・[ASP(Active Server Pages)]の解説。
・[元コンビニ店長時代の話]が弟に巻き込まれ、失敗した脱サラ、畑違い?の仕事で失敗。
・[プログラマーの愚痴]では、あまり見せたくない三流プログラマーの内面かな。
三流君を踏み台にする
主に上記4つの分類でHP作成やメルマガの発行を行ってます。
※更新頻度が落ちていて情報の鮮度が悪いです。

三流解説動画の再生リスト
https://www.youtube.com/user/ken3video/playlists

本当に三流なんです(笑):たまにスゴイですねなんて言われることもありますが、
真実は→ [三流君の真実は...] ←を初めに見てくださるとわかると思います。
(からくりは、成功例↑しか載せてなくて ヒドイ失敗例はお蔵入り迷宮入りが多かったりします)