MDBへのSQL文 Format関数使用

元の三流解説は、
三流君ASP:MDBへのSQL文 Format関数使用
↑を見て、笑ってやってください。
ブログに過去のソースコードをアップして、ブログの検索機能で利用してます(利用予定です)
※古くさいコードが多いです・・・

ソースコード

<%@LANGUAGE=VBScript%>
<html>
<head><META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=x-sjis">
<title>ADO から MDB へのSQL文でFormat関数使用</title>
</head>
<body>
<h1>ADO から MDB へのSQL文でFormat関数使用</h1>
test040-1.asp<br>
<hr>
<b>YYYYMMDDでデータをまとめて集計表示します。</b><br>
<font color="red">GROUP BY Format(WriteTime, 'YYYYMMDD')でまとめてみた。</font><br>
<font color="blue">※<b>Format</b>関数、ASP(<b>VBScript</b>)には無いです、<br>
<b>ADOのSQL文</b>で使用可能な例です</font><br>
<hr>
<%
  'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
  Set db=Server.CreateObject("ADODB.Connection")

  '.Provider？プロバイダー？通信会社？じゃなくって
  'データアクセスにはJet.OLEDB.4.0を使うことを設定
  db.Provider = "Microsoft.Jet.OLEDB.4.0"

  '次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
  db.ConnectionString = Server.MapPath("cnt_asp.mdb")

  'やっとデータベースを開ける
  db.open

  'FORMAT関数を使用して、テーブル名logからデータを集計する
  'ＳＱＬ文を発行する

  strSQL = "Select Format(WriteTime, 'YYYYMMDD') AS YYYYMMDD, Count(*) AS CNT"
  strSQL = strSQL & " From log"
  strSQL = strSQL & " GROUP BY Format(WriteTime, 'YYYYMMDD')"

  'オマケで画面にデータ表示
  Response.Write "<hr>発行する（した）ＳＱＬ文は<br><B><font color='green'>"
  Response.Write strSQL & "</font></B><br>です<hr>"

  Set rs = db.Execute(strSQL)

  'データの表示をテーブルで行う
  Response.Write "<TABLE Border='1'>"

  '見出しをバカっぽく、そのまま書き込む
  Response.Write "<TR>"
  Response.Write "<TD>NO.</TD>"
  Response.Write "<TD>日付</TD>"
  Response.Write "<TD>閲覧ページ数</TD>"
  Response.Write "</TR>"

  'ＥＯＦまでループ
  nCNT = 1
  Do While rs.EOF = False   '.EOFがFalseの間
    Response.Write "<TR>"   '内容を表示する
    Response.Write "<TD>" & nCNT & "</TD>"
    Response.Write "<TD>" & rs.Fields.Item("YYYYMMDD") & "</TD>"
    Response.Write "<TD ALIGN='RIGHT'>" & rs.Fields.Item("CNT") & "</TD>"
    Response.Write "</TR>" & Chr(13) & Chr(10)

    '次のレコードにポインタを移動する
    rs.MoveNext    'これを忘れると悲惨なことに、、、

    'カウンタを増やす
    nCNT = nCNT + 1
  Loop

  Response.Write "</TABLE>"  'テーブルは終わりです

  '開いていたレコードセットを閉じる
  rs.Close

  'データベースも閉じようよ
  db.Close

  'お行儀よくオブジェクトも開放しましょう（通常は自動的に解放されるけど）
  Set db = Nothing

%>
<hr>
終了です。<br>

</body>
</html>