asp054.html 三流君ASP:ADOでSQL Select * INTO文発行でExcel(*.xls)を作成する

元の三流解説は、
三流君ASP:ADOでSQL Select * INTO文発行でExcel(*.xls)を作成する
↑を見て、笑ってやってください。
ブログに過去のソースコードをアップして、ブログの検索機能で利用してます(利用予定です)
※古くさいコードが多いです・・・

ソースコード

<%@LANGUAGE=VBScript%>
<html>
<head>
<title>ADO Select * INTO [Excel 8.0;Database=Drive:\Path\File].[Sheet]</title>
</head>
<body>
<h1>ADO Select * INTO [Excel 8.0;Database=Drive:\Path\File].[Sheet]</h1>
test054-1.asp<br>
[Excel 8.0;database=ファイル名.xls].[シート名]<br>
を指定して、<br>
SELECT * INTO文を発行し、Excelファイルを作成する<br>
<hr>
<%
  'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
  Set db=Server.CreateObject("ADODB.Connection")

  'データアクセスにはJet.OLEDB.4.0を使うことを設定
  db.Provider = "Microsoft.Jet.OLEDB.4.0"

  '次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
  db.ConnectionString = Server.MapPath("db026.mdb")

  'やっとデータベースを開ける
  db.open

  '送り元のテーブル情報 TESTテーブルからIDの降順
  strFROM = " FROM TEST ORDER BY ID DESC"

  'Excelファイルの位置とシート名(送り先)を作成する
  T = Now()  '現在時刻を保存

  strMM = Right("0" & Month(T), 2)   '年月日を作る
  strDD = Right("0" & Day(T), 2)
  YYYYMMDD = Year(T) & strMM & strDD

  strH = Right("0" & Hour(T), 2)     '時分秒を作る
  strM = Right("0" & Minute(T), 2)
  strS = Right("0" & Second(T), 2)

  strFNAME = Server.MapPath("temp\a" & YYYYMMDD & ".xls") 'ファイル名
  strSNAME = "s" & strH & strM & strS   'シート名
     '↓接続用の文字列をファイル名、シート名を使って作成
  strXLS = "[Excel 8.0;database=" & strFNAME & "].[" & strSNAME & "]"

  'SQL文の作成
  strSQL = "SELECT * INTO " & strXLS & strFROM

  'テストで作成文字列の表示
  Response.Write "作成FILEは<b>" & strFNAME & "</b><br>"
  Response.Write "シート名は<b>" & strSNAME & "</b><br>"
  Response.Write "接続文字列<b>" & strXLS & "</b><br>"
  Response.Write "発行ＳＱＬ<b>" & strSQL & "</b><br>"

  set RET = db.Execute(strSQL) 'SQL文の発行

  'データベースも閉じようよ
  db.Close

  'お行儀よくオブジェクトも開放しましょう（通常は自動的に解放されるけど）
  Set db = Nothing

%>
<hr>
作成終了です。<br>
作成された<A href="temp/a<%=YYYYMMDD%>.xls" Target="_Blank">
a<%=YYYYMMDD%>.xls</a>の確認（保存は右ボタンで、クリックで開きます）<br>
<A href="test028-2.asp" Target="_Blank">db026.mdbのデータを見る</a><br>
<A href="test027-2.asp" Target="_Blank">db026.mdbへデータを登録する</a><br>

</body>
</html>