asp069.html 三流君ASP:FileSystemObjectの.GetTempName(一時ファイル名作成)

元の三流解説は、
三流君ASP:FileSystemObjectの.GetTempName(一時ファイル名作成)
↑を見て、笑ってやってください。
ブログに過去のソースコードをアップして、ブログの検索機能で利用してます(利用予定です)
※古くさいコードが多いです・・・

ソースコード

<%@LANGUAGE=VBScript%>
<html>
<head><META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=x-sjis">
<title>FileSystemObjectの.GetTempName(一時ファイル名を作成する)</title>
</head>
<body>
<h2>一時ファイル名を作成する<br>FileSystemObjectの.GetTempName</h2>
<b>FileSystemObjectの.GetTempName</b>を使用して、一時ファイル名を取得してみます<br>
<br>
.GetTempNameを使用すると、一時ファイルの名称を作成してくれます。<br>
あとは、その名称を使用して、ファイルを作成します<br>
(自動的にファイルは作られないので注意してください)<br>
※下記の実行結果とソースを見てください。<br>
<hr>
<%
  '*1 FileSystemObjectを生成します、、って英文、そのままジャン。
  Set objFS = Server.CreateObject("Scripting.FileSystemObject")

  '*2 .GetTempNameを使用して、一時ファイル名を作成する
  strTEMPNAME = objFS.GetTempName  '.GetTempNameを使用してリターン値をもらう
  Response.Write ".GetTempNameで作成した名称[<b>" & strTEMPNAME & "</b>]<br>"

  '現在のフォルダーから相対位置のworkディレクトリの名称を取り出す
  strFDIRNAME = Server.MapPath("work/") 'フォルダー名取得

  'work/xxxxのファイルを作成して、テストデータを書き込む
  Response.Write strFDIRNAME & "\" & strTEMPNAME & "を作成<br><br>"
  Set objTEXTFILE = objFS.CreateTextFile(strFDIRNAME & "\" & strTEMPNAME)
  objTEXTFILE.WriteLine "現在時刻は" & Now()
  objTEXTFILE.WriteLine "テンポラリファイルのテストでした(笑)"
  objTEXTFILE.Close
  Set objTEXTFILE = Nothing

  '確認でファイルリストの表示.GetFolderで取得後、一覧表示
  Response.Write strFDIRNAME & "のファイル一覧です<br>" & vbCRLF
  Set objDIR = objFS.GetFolder(strFDIRNAME)

  '.Filesコレクションにアクセスする
  For Each objFILE In objDIR.Files
    strFNAME = objFILE.Name  '取り出したobjFILEの.Nameを取得
    If strFNAME = strTEMPNAME Then Response.Write "<b>"
    Response.Write "<a href='work/" & strFNAME & "'>"
    Response.Write strFNAME & "</a>" & vbTab
    'おまけで更新日の表示
    Response.Write objFILE.DateLastModified & "<br>" & vbCRLF
    If strFNAME = strTEMPNAME Then Response.Write "</b>"
  Next

%>
<hr>
<a href="test069-1.asp"><b>再度</b>テンポラリファイルを<b>作成</b>する</a><br>

<a href="test071-1.asp">テストのテンポラリファイルを<b>削除する</b></a><br>
<br>
</body>
</html>