asp080.html 三流君ASP:Microsoft Text Driver (*.txt; *.csv) で接続してみた

元の三流解説は、
三流君ASP:Microsoft Text Driver (*.txt; *.csv) で接続してみた
↑を見て、笑ってやってください。
ブログに過去のソースコードをアップして、ブログの検索機能で利用してます(利用予定です)
※古くさいコードが多いです・・・

ソースコード

<%@LANGUAGE=VBScript%>
<html>
<head><META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=x-sjis">
<title>ADO Driver={Microsoft Text Driver (*.txt; *.csv)};DBQ=で接続</title>
</head>
<body>
<h1>ADO Driver={Microsoft Text Driver (*.txt; *.csv)};DBQ=で接続</h1>
test080-1.asp<br>
ASPからADOを使用してテキストファイル(*.csv)に接続を行う<br>
ファイル名はtest080.csvで、データは,カンマで区切られてます。<br>
<pre>
<Font Color='Green'>'SQLのテーブル名には、ファイル名を指定します。</Font>
strSQL = &quot;select * from test080.csv&quot;
<Font Color='Green'>'接続情報の作成 ドライバーの指定と、DBQには、パスのみを指定する</Font>
Con = &quot;Driver={Microsoft Text Driver (*.txt; *.csv)};DBQ=&quot; &amp; _
      Server.MapPath(&quot;.&quot;) &amp; &quot;;&quot;
'↑MapPathに(&quot;.&quot;)を渡し、カレントディレクトリを渡す
</pre><br>
こんな感じで作成してみました。（詳細は下のほうにあるソースを見てください）
<hr>
<%

  'ADO DB Recordset オブジェクトを作成する、英文そのままじゃん
  Set rs=Server.CreateObject("ADODB.Recordset")

  'SQLのテーブル名には、ファイル名を指定します。
  strSQL = "select * from test080.csv"
  '接続情報の作成 ドライバーの指定と、DBQには、パスのみを指定する
  Con = "Driver={Microsoft Text Driver (*.txt; *.csv)};DBQ=" & _
        Server.MapPath(".") & ";"
  '↑MapPathに(".")を渡し、カレントディレクトリを渡す

  Response.Write "使用する接続文字列は<br>"
  Response.Write "<STRONG><CODE>" & Con & "</CODE></STRONG><br>"
  Response.Write "発行するSQL文字列は<br>"
  Response.Write "<STRONG><CODE>" & strSQL & "</CODE></STRONG><hr>"

  '接続文字列、SQLを渡して、レコードセットを開く
  rs.Open strSQL, Con, 0  '0=adOpenForwardOnly

  'データの表示をテーブルで行う
  Response.Write "<TABLE Border='1'>"

  '見出しを(フィールド名を)そのまま書き込む
  Response.Write "<TR>"
  For Each fld_A In rs.Fields 'フィールドのアイテムに対してループ
     Response.Write "<TH>" & fld_A.Name & "</TH>" '←.Nameでフィールド名
  Next
  Response.Write "</TR>"

  'お約束のＥＯＦまでループは(データが無くなるまでループ)、
  Do While rs.EOF = False   'レコードセットの.EOFがFalseの間
    Response.Write "<TR>"   '内容を表示する
    For Each fld_A In rs.Fields 'フィールドのアイテムに対してループ
       Response.Write "<TD>" & fld_A.Value & "</TD>" '←.Valueでフィールドの値
    Next
    Response.Write "</TR>"
    rs.MoveNext    '次のレコードに移動する
  Loop

  Response.Write "</TABLE></SAMP>"  'テーブルは終わりです

  '後始末
  rs.Close '開いていたレコードセットを閉じる
  Set rs = Nothing 'お行儀よくオブジェクトも開放しましょう

%>
<hr>
[<a Href="test080.csv" TARGET="_blank">元ファイルtest080.csvを開く</a>]<br>
</body>
</html>